Validieren mit Stylesheets (Ein Tutorium)

<?xml version="1.0" encoding="iso-8859-1"?>
<Maschinenmodell>
  <Zustand id="Aus">
    <Übergang oper="A1" ziel="Ein"></Übergang>
  </Zustand>
  <Zustand id="Ein">
    <Übergang oper="A0" ziel="Rest"></Übergang>
  </Zustand>
  <Zustand id="Rest">
    <Übergang oper="L" ziel="Aus"></Übergang>
    <Übergang oper="A1">
      <Warnung>Schäden durch Flüssigkeit im Behälter</Warnung>
    </Übergang>
  </Zustand>
</Maschinenmodell>

Bedienungsanleitung und Maschinenmodell

Um nun die Bedienunganleitung gegen das Maschinenmodell validieren zu können, muss man erst einmal ein Verbindung zwischen beiden herstellen. Zum Beispiel kann man das Modell als eine externe Entität in die Bedienungsanleitung integrieren (Datei pumpe.xml):

<?xml version="1.0" encoding="iso-8859-1"?>
<!DOCTYPE anleitung SYSTEM "anleitung.dtd" [
  <!ENTITY maschinenmodell SYSTEM "pumpenmodell.xml">
]>
<Anleitung>
  &maschinenmodell;
  <Text>
  [...]
  </Text>
</Anleitung>

Die Beschreibungen der einzelnen Handlungssequenzen finden dann ihren Platz in dem Text-Element der Anleitung.

Für dieses Beispiel wird eine sehr einfache Logik für die Validierung zu Grunde gelegt: Wenn die Handlungssequenz eine Aufforderung zu einer Operation enthält, für die es eine Warnung gibt, muss die Bedienungsanleitung einen Warnhinweis enthalten, der sagt, bei welchem Zustand der Maschine es mit dieser Operation Probleme geben kann.

Die wichtigste daraus folgende Änderung bei der Erfassung der Anleitung gegenüber der ursprünglichen Version ist, dass bei jeder Aufforderung auch die Operation, die durchgeführt werden soll, als ein Attribut angegeben werden muss:

<Aufforderung oper="A1">Schalter A auf Position 1 stellen.</Aufforderung>

Ebenso muss bei den Wanrhinweisen festgehalten werden, auf welchen Zustand sie sich beziehen:

<Warnhinweis zust="Rest">Sachschäden durch überlaufende Flüssigkeit!
Behälter vor dem Einschalten leeren.</Warnhinweis>

Das Stylesheet

Wenn zusätzlich zu dem Modell der Maschinen diese Angaben vorhanden sind, kann man mit einem XSLT-Stylesheet die vollständigkeit der Warnungen überprüfen. Den Ansatz, Stylesheets zu benutzen, um eine nicht als Übereinstimmung mit einer Grammatik verstandene Validierung von Dokumenten durchzuführen, hat vor allem das Schematron von Rick Jelliffe populär gemacht. Der hier verfolgte Ansatz ist stark vom Schematron inspiriert worden, allerdings ist das Schematron für die hier angestrebte Funktionalität nicht flexibel genug. Es dürfte aber nicht schwierig sein, ein Stylesheet, das nach dem hier beschriebenen Muster aufgebaut ist, mit einem Schematron Stylesheet zu kombinieren.

Der erste Schritt des Stylesheets (Datei val-anleitung.xsl) ist es, einen Schlüssel zu erzeugen, der es erlaubt, über die Bezeichnungen der mit Wanungen versehenen Operationen auf die Zustände des Modells der Maschine zuzugreifen:

<xsl:key name="Warnungen"
         match="/Anleitung/Maschinenmodell/Zustand"
         use="Übergang[Warnung]/@oper" />

Die Bearbeitung der Datei wird durch ein Template gestartet, das das Ergebnis mit etwas HTML umgibt und sonst nichts weiter macht, als für die weitere Verarbeitung einen Modus zu setzen, in dem der normale Text des Dokuments nicht ausgegeben wird:

<xsl:output method="html"/>
<xsl:template match="/">
  <dl>
    <xsl:apply-templates mode="M1"/>
  </dl>
</xsl:template>
<xsl:template match="text()" priority="-1" mode="M1"/>

Die eigentliche Logik steckt in dem Template, das in diesem Modus für die Verarbeitung der in einer Handlungssequenz enthaltenen Aufforderungen zuständig ist:

<xsl:template match="Handlung/Aufforderung" priority="4000" mode="M1">

Das Template weist zunächst drei relativ zu der aktuellen Aufforderung definierte Größen an Variablen zu und bearbeitet dann mit Hilfe des anfangs definierten Schlüssels alle Zustände aus dem Modell der Maschine, für die es Warnungen bezüglich der aktuellen Operation gibt:

  <xsl:variable name="oper" select="@oper"/>
  <xsl:variable name="handlung" select="../Ziel"/>
  <xsl:variable name="warnhinweise" select="../Warnhinweis"/>
  <xsl:for-each select="key('Warnungen',$oper)">

Die Zwischenspeicherung in Variablen ist notwendig, da innerhalb dieses xsl:for-each-Elements die Zustände des Modells und nicht mehr die Aufforderungen in der Handlungssequenz der aktuelle Kontext der Verabeitung sind.

Für jeden dieser Zustände wird dann getestet, ob es in der Anleitung einen ihm entsprechenden Warnhinweis gibt. Wenn es keinen gibt, wird eine Warnung ausgegeben, die das Ziel der aktuellen Handlungssequenz, die Operation, den problematischen Zustand und den Text der im Maschinenmodell enthaltenen Warnung ausgibt, hier wieder in etwas HTML verpackt:

    <xsl:variable name="zustand" select="@id"/>
    <xsl:if test="count($warnhinweise[@zust=$zustand]) = 0">
      <dt><xsl:apply-templates select="$handlung"/></dt>
      <dd>Operation "<xsl:value-of select="$oper"/>":
          Problem möglich mit Zustand "<xsl:value-of select="@id"/>":
      <br />
        <xsl:apply-templates
            select='Übergang[@oper=$oper]/Warnung'/>
      </dd>
    </xsl:if>
  </xsl:for-each>
  <xsl:apply-templates mode="M1"/>
</xsl:template>

Wenn alles in Ordnung ist, produziert das Stylesheet nur eine leere Liste von Typ dl. Fehlt in dem Beispiel dagegen die Warnung, den Behälter vor dem Einschalten der Pumpe zu leeren, sieht das Ergebnis so aus:

Vorbereiten der Pumpe

Operation "A1": Problem möglich mit Zustand "Rest":
Schäden durch Flüssigkeit im Behälter

Je nach Vorlieben und Funktionsumfang des XSLT-Prozessors kann man dafür natürlich auch andere Darstellungsformate wählen, die es z. B. ermöglichen können, dass der für die Erstellung der Anleitung benutzte Editor gleich an die Stelle springt, an der der Warnhinweis fehlt.